Macros

Macros Available:

• AFK Macros
• Buddy Check
• Devil's Island Directions
• East Forest Directions
• Foothills Directions
• Friend Labeler
• Groar Caves Directions
• Hands Free
• Hive Directions
• KI Boat
• KI Tree Map
• Kudzu Bag
• Map Links
• Marsh Directions
• McBollie Caverns Directions
• Orga Eye Safe Equipper
• Orga Outback Directions
• Orga Outback Stepped Directions
• Pathfinder List Checker
• Random Dance
• Rescue Sunstone
• Snaggy Directions
• Speed Chain
• Tanglewood Directions
• URL Giver
• Use It Dammit!

URL Giver Macro

To use, copy and paste the following text into your Clan Lord macros file. Feel free to customize for your own use as needed.

// URL Giver v1.1
// Macro created by Kiriel D'Sol
// edited by Hidden T. Thoom
// Gives out commonly requested URLs in the format specified
// Notify kiriel@windsofdawn.org if you find a mistake or want
// to suggest an improvement

// Urls- add as many as you like, following the format
// be sure to update the count
setglobal @url_keywords[0] "scribia"
setglobal @url_urls[0] "http://www.sourceforge.net/projects/scribia/"
setglobal @url_titles[0] "Scribia"

setglobal @url_keywords[1] "tmn"
setglobal @url_urls[1] "http://www.thoomcare.com/"
setglobal @url_titles[1] "TMN (ThoomcareŞ Media Network)"

setglobal @url_keywords[2] "skills"
setglobal @url_urls[2] "http://www.windsofdawn.org/skills/"
setglobal @url_titles[2] "Winds of Dawn Professional Skills Lists"

setglobal @url_keywords[3] "faq"
setglobal @url_urls[3] "http://www.macinsearch.com/users/clanlordfaq/"
setglobal @url_titles[3] "Clan Lord FAQ"

setglobal @url_keywords[4] "newhelp"
setglobal @url_urls[4] "http://www.windsofdawn.org/newexilehelp/"
setglobal @url_titles[4] "New Exile Help"

setglobal @url_keywords[5] "ki"
setglobal @url_urls[5] "http://www.sundragonclan.com/maps/kismiaisle.gif"
setglobal @url_titles[5] "Kizmia's Isle Map"

setglobal @url_count 6

"url"
{
 set site @text.word[0]
 set format @text.word[1]
 set person @text.word[2]

 set url ""
 set title ""
 set command ""

 if format == ""
  set format "speak"
 end if

 // Error handling
 if site == ""
  message "No site specified."
  call url_usage
  goto end
 else if format == "thinkto"
  if person == ""
   message "No exilename specified to thinkto."
   call url_usage
   goto end
  end if
 else if format == "thank"
  if person == ""
   message "No exilename specified to thank."
   call url_usage
   goto end
  end if
 end if

 setglobal i 0
 label site_search_loop

 if @url_keywords[i] == site
  set url @url_urls[i]
  set title @url_titles[i]
 end if
 
 setglobal i + 1
 if i < @url_count
  goto site_search_loop
 end if
 
 if url == ""
     message "Specified URL not found."
     goto end
 end if
  
 // Give url in the requested format
 if format == "speak"
  set command ""
 else if format == "thinkto"
  set command "/thinkto "
  set command + person
  set command + " "
 else if format == "thank"
  set command "/thank "
  set command + person
  set command + " "
 else
  set command "/" 
  set command + format
  set command + " "
 end if

 if format == "message"
  message title " scroll: " url
 else
  command
  title
  " scroll: "
  url
  "\r"
 end if
 
 label end
}

url_usage
{
    message "Usage: url sitename format exilename"
    message "Format can be: speak, think, thank, thinkto, yell, whisper or message (only viewable by yourself)."
	message "If no format is specified, speak is used."
	message "Exilename is only used if you specify thinkto or thank."
}